Расчёт теплоотдачи регистра отопления

Как рассчитать теплоотдачу регистров отопления из гладких труб? С таким вопросом сталкиваются многие строители и проектировщики осуществляя подбор регистров отопления для конкретного помещения. Существуют определенные методики расчета, а также специальные приложения и программы, например калькулятор мощности регистров отопления. Их и рассмотрим в нашей статье.

Одним из самых простых и доступных методик расчета теплоотдачи регистров является расчет в Excel. Мы подготовили для Вас специальный документ, позволяющий произвести указанные расчеты. На примере выбранных данных произведем расчеты теплоотдачи конкретного регистра.

Расчет теплоотдачи регистра отопления

Регистр отопления из четырех гладких труб и схема движения теплоносителя показаны на рисунке.

На схеме четко показано каким образом перемещается теплоноситель внутри отопительного регистра. В целях поддержания в помещениях определенных температурных условий и соблюдения СнИПов требуется производить расчет теплоотдачи регистра отопления. Для осуществления расчетов теплоотдачи Вам потребуется скачать файл Excel на компьютер.

 

Расчет теплоотдачи регистра отопления (скачать .xls)

 

Более подробно рассмотрим как воспользоваться указанным файлом для получения результатов о теплоотдачи отопительных регистров.

 

Исходные данные, которые могу потребоваться для расчета:

Исходных данных не много, они понятны и просты.

1. Диаметр труб Dв мм заносим

в ячейку D3: 108,0

2. Длину регистра (одной трубы) Lв м записываем

в ячейку D4: 1,250

3. Количество труб в регистре Nв штуках пишем

в ячейку D5: 4

4. Температуру воды на «подаче» t_пв °C заносим

в ячейку D6: 85

5. Температуру воды на «обратке» t_ов °C пишем

в ячейку D7: 60

6. Температуру воздуха в помещении t_вв °C вводим

в ячейку D8: 18

7. Вид наружной поверхности труб выбираем из выпадающего списка

в объединенных ячейках C9D9E9: «При теоретическом расчете»

8. Постоянную Стефана-Больцмана C₀ в Вт/(м²*К⁴) заносим

в ячейку D10: 0,00000005669

9. Значение ускорения свободного падения g в м/с² вписываем

в ячейку D11: 9,80665

 

Меняя исходные данные можно смоделировать любую «температурную ситуацию» для любого типоразмера регистра отопления!

Теплоотдача просто одиночной горизонтальной трубы также может легко быть посчитанной по этой программе! Для этого достаточно указать количество труб в регистре отопления равное единице (N=1).

Результаты полученные при расчете теплоотдачи и их интерпретация

1. Степень черноты излучающих поверхностей труб εавтоматически определяется по выбранному виду наружной поверхности

в ячейке D13: =ИНДЕКС(H5:H31;G2) =0,810

В базе данных, расположенной на одном листе с программой расчета, для выбора представлены 27 видов наружных поверхностей труб и их степени черноты. (Смотри в файле для скачивания в конце статьи.)

1. Среднюю температуру стенок труб t_ст в °C вычисляем

в ячейке D14: =(D6+D7)/2 =72,5

t_ст=(t_п+t_о)/2

2. Температурный напор dt в °C рассчитываем

в ячейке D15: =D14-D8 =54,5

dt=t_ст— t_в

3. Коэффициент объемного расширения воздуха β в 1/K определяем

в ячейке D16: =1/(D8+273) =0,003436

β=1/(t_в+273)

4. Кинематическую вязкость воздуха ν в м²/с вычисляем

в ячейке D17: =0,0000000001192*D8^2+0,000000086895*D8+0,000013306 =0,00001491

ν=0,0000000001192*t_в²+0,000000086895*t_в+0,000013306

5. Критерий Прандтля Pr определяем

в ячейке D18: =0,00000073*D8^2-0,00028085*D8+0,70934 =0,7045

Pr=0,00000073*t_в²-0,00028085*t_в +0,70934

6. 16. Коэффициент теплопроводности воздуха λ рассчитываем

в ячейке D19: =-0,000000022042*D8^2+0,0000793717*D8+0,0243834 =0,02580

λ=-0,000000022042*t_в²+0,0000793717*t_в+0,0243834

7. Площадь теплоотдающих поверхностей труб регистра A в м² определяем

в ячейке D20: =ПИ()*D3/1000*D4*D5 =1,6965

A=π*(D/1000)*L*N

8. Тепловой поток излучения с поверхностей труб регистра отопления Q_и в Вт вычисляем

в ячейке D21: =D10*D13*D20*((D14+273)^4- (D8+273)^4)*0,93^(D5-1) =444

Q_и=C₀*ε*A*((t_ст+273)⁴— (t_в+273)⁴)*0,93^(N-1)

9. Коэффициент теплоотдачи при излучении α_и в Вт/(м²*К) рассчитываем

в ячейке D22: =D21/(D15*D20) =4,8

α_и=Q_и/(dt*A)

1. Критерий Грасгофа Gr вычисляем

в ячейке D23: =D11*D16*(D3/1000)^3*D15/D17^2 =10410000

Gr=g*β*(D/1000)³*dt/ν²

1. Критерий Нуссельта Nu находим

в ячейке D24: =0,5*(D23*D18)^0,25 =26,0194

Nu=0,5*(Gr*Pr)^0,25

2. Конвективную составляющую теплового потока Q_к в Вт вычисляем

в ячейке D25: =D26*D20*D15 =462

Q_к=α_к*A*dt

3. А коэффициент теплоотдачи при конвекции α_к в Вт/(м²*К) определяем соответственно

в ячейке D26: =D24*D19/(D3/1000)*0,93^(D5-1) =5,0

α_к=Nu*λ/(D/1000)*0,93^(N-1)

4. Полную мощность теплового потока регистра отопления Q в Вт и Ккал/час считаем соответственно

в ячейке D27: =(D21+D25)/1000 =0,906

Q=(Q_и+Q_к)/1000

и в ячейке D28: =D27*0,85985 =0,779

Q’=Q*0,85985

5. Коэффициент теплоотдачи от поверхностей регистра отопления воздуху α в Вт/(м2*К) и Ккал/(час*м2*К) находим соответственно

в ячейке D29: =D22+D26 =9,8

α=α_и+α_к

и в ячейке D30: =D29*0,85985 =8,4

α’=α*0,85985

На этом расчет в Excel завершен. Теплоотдача регистра отопления из труб найдена!

Расчеты многократно подтверждены практикой!

Теплотехническим расчетам на этом сайте посвящены также статьи: «О тепловой энергии простым языком!», «Расчет водяного отопления за 5 минут!». В них просто и понятно на примерах рассказывается об основных понятиях теплотехники.

Замечания при расчетах

1. Правильнее в расчетах было бы использовать не коэффициент теплоотдачи α между наружными стенками регистра и воздухом, а коэффициент теплопередачи k, учитывающий теплообмен между теплоносителем (водой) и внутренними стенками труб регистра отопления, а так же передачу тепла через материал стенки (термическое сопротивление стенки). Рассчитывается коэффициент теплопередачи от воды к воздуху помещения по формуле:

k=1/(1/α₁+s_ст/λ_ст+1/α)

Но так как:

α₁≈2000…3000 Вт/(м²*К) – коэффициент теплоотдачи между водой и внутренней стальной стенкой

s_ст≈0,002…0,005 м – толщина стенок труб

λ_ст≈50…60 Вт/(м*К) – коэффициент теплопроводности материала стенок труб

То:

1/α₁≈0

s_ст/λ_ст≈0

И следовательно:

k≈α

2. Теплоотдача регистров отопления зависит от способа подачи воды в них (сверху вниз, снизу вверх …), от монтажных расстояний до ограждающих конструкций (до пола, до подоконника, до стены, до экрана), от толщины лакокрасочного покрытия и прочих факторов. Фактическая теплоотдача может быть меньше расчетной на 15…20%. Это необходимо учитывать при окончательных расчетах!
3. Расстояние между трубами и количество труб также оказывают влияние на теплоотдачу регистров отопления. В программе это частично учтено применением понижающего коэффициента (0,93) на каждый дополнительный ряд труб. Расстояние между трубами желательно выдерживать не менее диаметра трубы D (больше — лучше).
4. Коэффициент теплопередачи k не является постоянной величиной для конкретного прибора отопления и значительно меняется  при изменении температурного напора dt!